| |
|
| |
| |
|
⊙ 비행장비 매뉴얼 입니다. |
| |
|
| |
| >>
Control
Manager Scripting [컨트롤 매니저 스크립트하기,CMS 프로그래밍 가이드) |
Introduction [서론]
컨트롤러 프로그래밍의 대부분은 GUI 도구를 이용해서 할 수 있지만, GUI로 직접 만들 수 없는 기능을
만들 필요가 있을 때도 있습니다. Control Manager는 그런 필요한 기능을 사용자가 만들 수
있도록 해주는 CMS라고 하는 뛰어난 텍스트 스크립트 도구를 포함하고 있습니다.
다음의 장들은 CMS의 기본, CMS Script Editor(CMS 스크립트 편집기)의 사용법,
CMS 스크립트 언어의 여러 부분, 그리고 간단한 예제들을 다룹니다. 스크립트를 직접 만들어보기 전에
이 장을 완벽히 읽어보아야 합니다.
CMS 스크립트는 대체로 배우기 쉽긴 하지만, “직관적”으로 알아서 쓸 수는 없습니다. 좀더 나은
작업을 하려면 여러 기능과 예제들을 공부하십시오.
CMS Basics [CMS의 기초]
CMS는 컨트롤러에 있는 컨트롤들을 직접 제어하는 기능을 합니다. CMS는 스크립트의 명령어에 따른
값을 처리하여, “CMS Controls”라고 하는 모의 컨트롤의 특수한 설정으로 처리되는 결과를 제공합니다.
다른 실제의 장치들과 마찬가지로 “Add” 버튼으로 CMS Controls를 맵에 추가할 수 있습니다.
CMS Controls는 Map Wizard를 이용할 때 스크립트 도구를 사용할 것이라고 선택하면 자동으로
맵에 추가되기도 합니다.
CMS를 사용할 때의 시스템 설정은 Mapped Mode를 이용할 때와 거의 비슷합니다.:
다른 점은 오른쪽 아래에 CMS Script와 CMS Controls가 그려져 있다는 것입니다.
개념적으로는, USB 장치에서 장치 생성 데이터(device-generated
data; 붉은 색으로 표시)를 직접 받아서 CMS 스크립트로 넘겨줍니다. 데이터는 스크립트에 들어있는
지시 목록에 따라서 처리되어 스크립트 생성 데이터(script-generated data; 파란 색으로
표시)를 산출합니다.
스크립트 생성 데이터는 “CMS Controls’라고 하는 모의 장치로 전해집니다. CMS Controls는
실제의 USB 장치처럼 버튼과 축의 값을 산출합니다.
이 데이터는 USB 장치의 축과 버튼들처럼 맵에서
프로그래밍해서 사용할 수 있습니다.
The
CMS Controls [CMS 컨트롤]
CMS Controls는 64축과 128 버튼으로 되어있습니다. 이를 맵에 추가하면, 다른 컨트롤러들에
쓰이는 Device Tab과 똑같이 동작하는 Device Tab이 Selection Pane에 나타납니다.
Selection Pane은 다음과 같이 보입니다:
이 CMS Controls는 Selection pane의 다른 컨트롤러들과 동일하게 작동합니다.
128개의 버튼과 64축 각각을 나타내는 지점들이 있습니다.
마우스를 그 위로 가져가면 그 지점이 어느 버튼이나 축인지를 표시해주는 팝업 라벨이 나타납니다. 라벨이
보일 때 마우스를 클릭하면 프로그래밍할 수 있도록 그 축이나 버튼이 선택됩니다.
Programming
the CMS Controls [CMS 컨트롤의 프로그래밍]
이 축과 버튼들을 프로그래밍하는 방법은 실제 장치들을 프로그래밍 하는 것과 똑같습니다.
Direct Mode로 작동하도록 설정하여 Control Manager Device의 축이나 버튼으로
지정할 수도 있고, Programmed Mode로 설정하여 키값을 전송하도록 할 수도 있습니다. Dialog
Pane에서는 실제의 장치에서와 같은 대화창이 쓰입니다.
CMS Controls와 실제 장치와의 다른 점은, CMS Controls에서는 CMS 스크립트 파일을
통해서 버튼과 축의 값을 정의한다는 것입니다. CMS는 실제 장치의 모든 버튼과 축들을 제어할 수 있습니다.
CMS 스크립트에서 정의한 대로 데이터가 조합되거나 수정되어 CMS Controls의 출력값으로 산출됩니다.
GUI는 CMS Controls가 Windows에서 활성화되거나 키값을 보내게끔 할 수 있도록 CMS
Controls를 Control Manager Device의 축과 버튼에 지정하는데 쓰입니다.
CMS Controls는 기본적으로 다른 실제의 CH 장치들과 똑같이 프로그램할 수 있는 하나의 큰
“자작” 조이스틱입니다.
Using the CMS Script Editor [CMS
스크립트 편집기의 이용]
CMS Script Editor는 맵에 부속된 CMS 스크립트 파일을 쓰고 수정하는데 쓰입니다.
에디터를 이용하기 전에, CMS 프로그래밍 가이드의 정보들을 터득해야 합니다. 배우기가 어렵지는 않지만,
기본적인 프로그래밍의 개념과 사용 기능들에 대한 지식이 필요합니다.
스크립트 파일은 항상 맵 파일과 연계됩니다. 맵을 불러오고 저장하면 자동으로 함께 불러지고 저장됩니다.
스크립트 파일은 맵 파일과 같은 이름을 가지지만 확장자는 .CMS로 다릅니다.
기본적으로 이것은 기본적으로 투과성을 띠며, Script Editor에 프로그래밍이 되어있지 않으면
맵 그 자체로는 아무 기능도 하지 않습니다.
에디터를 열면 다음 그림이 나타납니다:
CMS Editor 화면은 기본적으로 네 부분으로 구성됩니다.
맨 위쪽에는 에디터의 작업을 제어하는 여러 버튼들이 있는 툴바가 있습니다.
그 아래는 스크립트 파일을 입력하는 에디터 화면이 있습니다.
에디터 화면의 아래쪽에는 스크립트 구문을 테스트할 때 나타나는 에러 박스가 있습니다.
마지막으로, 데이터의 맨 아래에는 텍스트 커서의 위치를 보여주는 status bar가 있습니다.
Editor
Tool Bar [편집기 툴바]
Editor Tool Bar에는 에디터의 작동을 제어하는 여덟 개의 버튼이 있습니다.
Clear Script
“Clear Script”는 스크립트 파일에 있는 모든 프로그래밍을 지웁니다. 다음 그림처럼 생겼습니다:
스크립트는 기본 SCRIPT에서 ENDSCRIPT 상태로 바뀝니다.
Check Script
“Check Script” 버튼은 현재 에디터에 있는 스크립트의 에러를 테스트하는데 쓰입니다. 다음과
같은 아이콘입니다:
다운로드 하기 전과 같이 스크립트의 에러가 분석됩니다.
에러가 발견되면 텍스트 커서가 발견된 에러 지점에 위치되고 에디터 텍스트 구역의 아래쪽에 Error
Message 박스가 나타납니다. 메시지는 노란색 텍스트로 뜹니다.
스크립트에 이상이 없으면, 녹색 텍스트로 이상이 없다는 메시지를 알려주는 박스가 나타납니다. 마우스
버튼으로 클릭하면 Error Box는 사라집니다.
Cut, Copy, and paste Text Buttons
[잘라내기, 복사하기, 붙여넣기 버튼]
이 세 개의 버튼들은 기본 Windows 기능처럼 작동됩니다. “Cut(잘라내기)” 버튼은 다음의 아이콘입니다:
“Copy(복사하기)” 버튼은 다음 그림과 같습니다:
“Paste(붙여넣기)” 버튼은 다음 그림입니다.:
Help [도움말]
이 버튼을 누르면 메인 GUI에서와 같이 가이드가 열립니다. 한 가지 다른 점은 목차가 아니라 CMS
부분이 열린다는 것입니다. 아이콘은 다음과 같습니다:
What’s This? [도움말2]
Script Editor에는 “Whats’s This?” 버튼도 있습니다:
기능은 메인 GUI에서와 같습니다.
Close [종료]
“Close” 버튼은 CMS Script Editor를 종료시킵니다. 메인 GUI의 종료 버튼처럼 생겼습니다:
메인 GUI의 Close 버튼과 다른 점은, GUI를 종료하는 것이 아니라 에디터를 종료한다는 것입니다.
Editor
Screen [편집기 화면]
편집 영역의 아래쪽에는 Error Message 박스가 있습니다. 이 박스는 Check script
버튼을 사용할 때만 보입니다. 체크가 끝나면 스크립트 체크 작업의 상태 보고 창이 뜹니다.
에러가 발견되면, 노란 색의 메시지로 어느 부분에서 에러가 생겼는지 알려줍니다. 편집 화면의 텍스트
커서는 에러가 발생한 지점에 놓입니다. 에러 메시지는 보통 매우 분명하고 스크립트의 실제 에러는 보통
커서 위치(또는 그 바로 앞)입니다.
체크가 성공하면, 녹색 텍스트로 프로그램 여유공간을 얼마나 사용하였는지 알려주는 메시지가 나타납니다.
이 줄은 다음과 같은 식으로 표시됩니다:
Script Compiled Okay! P: 100/6144
K: 10/1024
“P:” 다음의 값은 스크립트가 얼마나 많은 스크립트 기억공간을 이용하고 있는지와 전체 스크립트
기억공간을 나타냅니다. 위의 예에서는, 6144크기의 기억공간 중 100만큼을 사용하고 있다는 뜻입니다.
“K:” 다음의 값은 얼마나 많은 constant location(고정 기억공간)을 사용하고 있는가를
뜻합니다. Constant는 스크립트에 다음과 같은 줄을 입력하면 생깁니다:
cms.a1 = 100;
Constant 값은 자동으로 100으로 만들어집니다. CMS는 또한 일정한 기능들을 위해 내부적으로
사용할 constant를 자체적으로 만듭니다. “K:” 값은 1024의 가용한 기억공간 중에서 스크립트가
사용하고 있는 양을 나타냅니다.
Status Bar
Editor 화면의 아래에는 Status Bar가 있습니다. 이 바는 editor 커서의 현재의 줄과
열을 보여주는 데에만 쓰입니다. 이 정보는 에러가 발견되었을 때 그 위치를 찾아가는데 유용합니다.
CMS
Script Elements [CMS 스크립트의 구성 요소]
Variables [변수]
“변수”가 CMS의 모든 것이라고 해도 과언이 아닙니다. 변수는 실제 컨트롤러와 CMS 컨트롤의 버튼과
축을 나타내는데 쓰이며, 매개의 결과는 스크립트의 처리에 따라 저장됩니다.
기본적으로 두 가지의 변수가 있는데, 하나는 아날로그 변수이고 또 하나는 Bit 변수입니다. 이 부분에서는
이 기본 변수의 형식과 용례들을 설명합니다.
Analog Variables [아날로그 변수]
우선 기본적인 형식은 “아날로그” 변수입니다. 아날로그 변수는 수치값을 나타내는데 쓰입니다. 이 값은
실제 장치의 현재 축값, CMS 컨트롤 축의 값, 또는 스크립트에서 정의한 연산 결과 등을 나타냅니다.
아날로그 변수는 연산에 충분하게끔 매우 넓은 영역을 가집니다. 그렇지만, 실제 장치의 축값은 항상
0에서 255까지 입니다. Control Manager 캘리브레이션 절차에서 이 값이 유지되며, 실제
장치에서 이 값들이 나타납니다.
CMS Controls의 축에 할당된 값들도 Control Manager Device로서 Windows로
전송되거나 Up/Down 이나 위치값을 전송하는데 쓰이므로, 역시 값은 0에서 255까지 입니다.
어떤 경우든 0에서 255까지가 최대값입니다.
CMS Controls에 값이 입력되기 전에 CMS 스크립트에서 값이 적당한 영역으로 조정됩니다.
CMS Controls 축에 0 미만의 값이 할당되면, 그 값은 0으로 간주됩니다.
값이 255보다 크면, 255로 간주됩니다. 이 법칙은 CMS Controls에 할당되어 맵에서 쓰일
경우에만 적용된다는 것을 주의해주십시오.
연산이나 기타 다른 작업중에는 수치들이 이 값의 영역을 넘을 수도 있습니다. 그렇지만 CMS에 문제를
일으키지는 않습니다.
JS1.A1과 같은 실제 컨트롤러 축에서 보면, 캘리브레이션을 하더라도 Range(값 범위)나 Gain(입력값
조정)값이 적용되기 전에 항상 스크립트의 값을 받습니다. 이는 스크립트가 컨트롤러 축에서 안정적으로
전체 영역의 비례 수치를 계산할 수 있다는 것을 뜻합니다.
지정된 Gain과 Range 매개변수들은 CMS 축에 제공되어 그에 해당하는 CMS Control
Manager Device에 전송될 때에만 적용됩니다. Gain과 Range 매개변수는 CMS 축이
Up/Down이나 위치 값을 전송하는데 쓰일 때는 적용되지 않습니다.
Bit Variables [비트 변수]
그다음 기본 형식은 “Bit”변수입니다. 비트 변수는 TRUE와 FALSE의 두 가지 값만을 가집니다.
이 값들은 실제 장치나 CMS Controls의 버튼 위치를 뜻하며, TRUE는 버튼이 눌린 것을,
FALSE는 버튼이 해제된 상태를 나타냅니다.
이 값들은 스크립트 파일에서 정의한 논리 연산, 계산 비교, 논리 장치의 출력, 기타 TRUE/FASLE
값이 필요한 기타 다른 이유로 인하여 산출될 수 있습니다.
Constants [상수]
상수는 스크립트에 수치로 입력되는 값입니다. 이 값들은 “241”과 같은 십진법의 아날로그 값이나 “TRUE”와
“FALSE”의 비트값이 될 수도 있습니다. 상수는 스크립트에서 상수값을 할당할 수 없는 경우만 아니면
다양한 용도로 쓰입니다.
상수는 필요할 때 스크립트에서 정의되며 “쓰기”는 불가능합니다. 다른 아날로그 값과 마찬가지로, 상수는
실제 장치에 할당할 수 없습니다.
현재 모드 설정에 따라 미리 지정되어야 하는 몇 가지의 상수가 있습니다. 이 수치들은 다음 장들에서
여러 가지 명칭으로 설명합니다.
Varlable Names [변수 이름]
CMS에서 쓰이는 모든 변수들은 정해진 이름이 있습니다. 이름들은 변수의 형식(아날로그인지 비트인지),
그리고 변수가 무엇을 나타내는지에 따릅니다. 그 중 후자의 경우는 실제 컨트롤러의 컨트롤, CMS Controls중의
하나, 또는 CMS에서 제공하는 내부 변수 등이 될 수 있습니다.
General Naming Conventions [일반 명명
규칙]
아날로그 변수는 “A”로 시작하고 해당하는 아날로그 변수를 나타내는 숫자가 붙으며, “A4”와 같은
식입니다. 이와 비슷하게, 비트 변수도 “B”로 시작해서 해당하는 비트 변수를 나타내는 숫자가 붙습니다.
“B14”처럼 말입니다. 이 원칙은 모든 변수들에 적용됩니다.
Variable Groups [변수 그룹]
변수들은 대개 몇 개의 그룹 안에 포함됩니다. 어떤 경우에는 변수의 이름 자체가 일정한 그룹을 구분하기도
합니다. 또 어떤 경우에는 변수 이름이 장치 이름 뒤에 “.”와 축이나 버튼의 ID가 뒤따르게끔 표시됩니다.
Real Controllers [실제 컨트롤러]
실제 컨트롤러인 맵에 있는 CH USB 장치는 “JS1”에서
JS16”까지(물론, 몇 개의 조이스틱을 가지고 있느냐에 따라)로 지정됩니다. “JS1” 컨트롤러는
GUI의 맵에서 Device Tab의 가장 왼쪽에 있습니다(“Program Settings”탭은 제외)
“JS2”는 그 오른 쪽에 있고, 그런 식으로 순서가 정해집니다.
그 컨트롤의 특정한 컨트롤을 지정하기 위해서는 컨트롤러의 ID, 다음에 “.”가 붙고 그다음에 아날로그
또는 비트 변수가 붙습니다. 예를 들면, 맵의 맨 왼쪽 장치 탭이 FighterStick이면, FighterStick의
X축은 다음과 같이 표현됩니다:
JS1.A1
그리고 그 스틱의 7번 버튼은 다음과 같이 됩니다:
JS1.B7
그 다음 오른쪽 탭의 장치가 Pro Throttle이라면, 마이크로 스틱의 버튼은 “JS2.B1”이
됩니다. 축과 햇의 경우에는 축과 버튼이 쉽게 식별되지는 않습니다. 이런 경우에는 GUI가 Dialog
Pane에서 장치 이름에 적절한 지정자를 부여하며, 찾을 때는 그것을 이용하면 됩니다.
예를 들면, CombatStick의 1번 햇은, 실제로 7번 버튼입니다. 이를 GUI에서는 “hat
1 Up [B7]”이라고 보여주며, 스크립트에서는 B7을 사용하게 됩니다.
마찬가지로, 스로틀 축은 “Throttle [A3]”이라고 보입니다.
JSx 장치에서 인식된 축들은 X축에서 V축까지가 각각“A1”에서 “A6”까지가 됩니다. 버튼은 “B1”에서
“B40”까지 입니다.
상한인 “B40”는 앞으로 더 늘릴 수 있게 하기 위한 것입니다. 실제로는 컨트롤러가 B16 이상의
버튼은 가지지 않습니다.
위의 규칙에 하나의 예외가 있습니다. 테스트 화면에서 버튼으로 나타나지 않더라도, 실제 장치의 POV
위치는 “B25”에서 “B32”까지의 버튼이 됩니다.
“B25”버튼은 “POV Up”이고, 거기서부터 숫자순으로 POV의 시계방향 위치 순서를 나타내어
“B32”는 “POV Up/Left”가 됩니다. 그러므로, 예를 들면 CMS 스크립트에서 POV Up
위치는 “JS1.B25”가 되고, POV Up/Right 위치는 “JS1.B26” 등이 됩니다.
이 이름들은 POV를 어떤 모드로 프로그램하는지와는 상관이 없으며, POV의 움직임에 따라서 설정되며,
또는 버튼이나 키값을 전송하도록 프로그래밍하여도 CMS 스크립트에서 B25…B32의 이름을 사용할 수
있습니다.
햇을 POV로 설정했을 때는 이 위치들은 테스트 화면에서 보이는 위치라는 것을 주의해주십시오. Pro
Throttle에서는, 이것이 실제의 위치와 반드시 일치하지는 않습니다.
한 예로, “POV Up”은 실제로는 햇을 오른쪽으로 움직이는 것입니다. 여기서부터 시계방향 순으로
다른 위치들도 정해집니다.
실제 장치의 축과 버튼에 값을 할당할 수는 없습니다. 이 값들은 장치 그 자체로만 제어됩니다. 그리고
이 값들은 읽기 전용입니다.
GUI에서 캘리브레이션이 정확히 되었다면 컨트롤에서 입력되는 아날로그 값의 범위는 0에서 255까지입니다.
CMS
Controls [CMS 컨트롤]
GUI에서 프로그램한 CMS Controls는 JSx 장치와 비슷하게 표시되지만, “JSx”가 아니라
“CMS”라는 접두사가 붙습니다. 예를 들면:
CMS.B1
CMS.A13
맵에서는 한 세트의 CMS Controls만이 있을 수 있으므로, 숫자 식별자는 필요가 없습니다.
CMS에는 “A1”에서 “A64”까지의 64축과, “B1”에서 B128”까지의 128 버튼이 포함됩니다.
이 값들은 CMS Controls 탭이 선택되어있을 때 GUI에서 프로그래밍할 수 있는 축과 버튼들과
일치합니다. CMS 변수는 읽기와 설정이 모두 가능합니다.
CMS는 변수값을 설정함으로써 CMS Control의 출력값을 제어합니다.
JSx 변수와 마찬가지로, CMS 아날로그 값의 범위도 0에서 255까지 입니다. 이 값을 넘을
수도 있지만, 초과된 값들은 Control Manager에 의해 최소값이나 최대값으로 나옵니다.
GUI에서 CMS Control 축을 지정할 때, 그 축은 CMS의 설정값인 0에서 255까지를 최대값과
최소값으로 가집니다.
Internal Variables [내부 변수]
CMS는 스크립트에서 사용할 내부 “스크래치 패드” 변수를 제공합니다. 이 변수들은 GUI에서 직접
프로그램할 수는 없으며, CMS Controls으로만 프로그램할 수 있습니다.
이 변수들은 저장작업 등에 쓰입니다. CMS Controls로 Control Manager Device
버튼과 축을 제어하거나 키값을 전송하는데 변수들이 실제로 필요하지 않을 때에만 쓰는 것이 좋습니다.
내부 변수에는 256개의 내부 아날로그 값들과 1024개의 비트 값이 있습니다. 이 값들은 어떤 “장치(device)”에도
연결되어있지 않으므로, 접두기호 없이 표기됩니다. 변수 이름들은 “A1”에서 A256”까지와, “B1”에서
B1024”까지입니다.
Device Variables [장치 변수]
“Device Variables(장치 변수)”라고 하는 변수들도 있습니다. 이 변수들은 스크립트 언어에
쓰이는 기능들, 특히 타이머의 현재 상태를 나타내는 비트 값입니다.
나중에 좀더 자세히 설명하겠지만, 지금은 그런 것이 있다는 정도만 말씀드리겠습니다. 장치 변수에는
256개의 값이 있으며, “D1”에서 “D256”까지로 이름지어지고 접두기호는 없습니다.
Special Variables [특별 변수]
CURRENTMODE라고 하는 또 하나의 내부 변수가 있습니다. 이것은 Control Manager의
현재 모드를 나타내며, 보통 FighterStick이나 Pro Throttle을 통해 설정됩니다.
CURRENTMODE 변수에 값을 지정할 수 있고, 그러면 맵은 위의 장치들에서 설정하는 대로 모드가
바뀌게 됩니다. 스크립트는 그 장치들의 LED 표시기에 영향을 주지는 못하지만, 스크립트를 통해 CURRENTMODE를
설정하면 Control Manager 모드와 조종장치의 LED가 연동됩니다.
Predefined Constants [선 지정 상수]
CURRENTMODE 변수를 설정하거나 체크하는데 쓰이는 세 가지의 선 지정 상수들이 있습니다. 이
값들은 MODE1, MODE2, MODE3이 각각 0, 1, 2에 대응합니다.
Operators [연산자]
Analog Operators [아날로그 연산자]
CMS는 아날로그값과 비트값의 “Operators(연산자)”를 제공합니다. 아날로그 값에 지원되는 연산자는
기본적인 계산기능을 하는 “+”, “-“, “*”, “/” 기호입니다.
JS1.A1 + 100 // Addition
CMS.A1 - A27 // Subtraction
A2 * 5 // Multiplication
JS1.A1 / 2 // Division
위 예들은 모두 아날로그 값으로 지정될 수 있는(JSx 변수는 제외) 유효한 아날로그 값을 산출합니다.
Logical Operators [논리 연산자]
논리 연산을 위해서, CMS는 AND, OR, NOT의 기능을 제공합니다. 논리연산자에 익숙하지 않은
경우를 위해, 연산은 매우 간단합니다.
예를 들면:
JS1.B1 AND JS1.B4
여기서는 JS1의 B1과 B4가 TRUE 상태이면 결과값이 TRUE가 됩니다.
OR도 비슷하게 쓰입니다:
JS1.B1 OR JS1.B4
여기서는 JS1의 B1이나 B4가 TRUE 상태이면 결과값이 TRUE가 됩니다.
NOT 연산자는 단순히 입력 상태를 반전시키는 것입니다. 보기:
NOT JS1.B1
여기서는 JS1.B1이 FALSE 상태라면 TRUE값이 되고, 그 반대도 같습니다.
Comparison Operators [비교 연산자]
비교 연산자는 아날로그 변수의 값들을 비교하는데 쓰입니다. 여기에는 여섯 개의 연산자가 있습니다. 단어나
기호를 모두 프로그래밍에 이용할 수 있습니다. 이 단어나 기호들은 연산결과가 서로 같습니다.
| Less Than (미만) |
"LT" 또는 "<" |
| Less Than or Equal To (이하) |
"LE" 또는 "<=" |
| Equal To (같다) |
"EQ" 또는 "==" ("="를 두번
씀) |
| Greater Than or Equal To (이상) |
"GE" 또는 ">=" |
| Greater Than (보다 크다) |
"GT" 또는 "<" |
| Not Equal To (같지 않다) |
"NE" 또는 "!=" |
이 연산자들의 이용은 스크립트 파일 만들기 부분에서 더 자세하게 다룹니다.
Assignment Operator [지정 연산자]
지정 연산자는 “=” 기호입니다. 이 연산자는 변수를 일정한 값으로 설정하게끔 해줍니다. 이는 상수,
축 값, 기타 저장된 값들입니다. 이 내용은 Statements(구문) 부분에서 다룹니다.
Expressions [연산식]
연산식은 기본적으로 값을 가지는 모든 것이며, 아날로그와 비트값 모두 가능합니다. 모든 변수들은 위에
설명한 연산자들을 이용하여 만들어지는 복잡한 연산인 연산식입니다. 연산식에는 필요에 따라 연산들을 묶어주는
괄호가 포함됩니다. 다음은 연산식의 예입니다.
JS1.B1 OR JS1.B2
(JS1.A1 + JS1.A2) / 2
(JS1.B1 AND JS1.B2) OR B2 OR (CMS.B1
AND CMS.B2)
연산식은 CMS Controls로 보내져서 맵의 현재 상태를 정의하는 값을 만드는데 쓰이는, CMS
스크립트의 초석입니다.
Scripting
Reference [스크립트 참고] -- PART 1
Basic Scripting [기본 스크립트 작업]
표준 스크립트 언어를 구체적으로 설명하기 전에, 작동방식을 간단히 설명하겠습니다. 우선 생각할 것은,
스크립트는 CMS가 Mapped Mode에 있을 때 처리“할 일의 목록”이라는 것입니다.
스크립트는 데이터 전송, 특정한 기능의 처리 등을 CMS에 알립니다.
목록의 각 항목들(statement; 명령구문이라고 하는)은 CMS가 제공하는 기능을 이용하여 실행할
행동들을 정의합니다.
스크립트를 만드는 것은 기본적으로 프로그램이 따라야 할 방향을 설정하는 것입니다. 필요한 항목들을
만드는 것은 간혹 까다롭기도 하지만, 기본적으로 해주어야 할 일입니다.
The Script Loop [스크립트 루프]
Control Manager의 작업은 다음과 같은 반복적인 “loop(주기성)”작업입니다.
1. 실제 장치에서 새 축값과 버튼 상태를 얻는다.
2. 스크립트에서 정의한 방법대로 새 값을 처리하여
CMS Controls에서 버튼과 축의 새 명령을 만든다.
3. GUI에서 만들어진 맵으로 새 CMS Control의
명령구문을 처리하여 Control Manager Device의 축과 버튼, 키값, 마우스 움직임을 만들어낸다.
4. 1단계로 돌아가서 위 과정을 반복한다.
루프는 기본적으로 실제 데이터의 변경, 지난 루프가 반복된 시간 등등 몇 가지 요인에 따라 일정하게
정기적으로 실행됩니다. 단순해 보이지만, 주의가 필요합니다.
2단계가 실행중일 때, 스크립트는 첫째 줄에서 시작하여 마지막 줄까지 처리합니다. 여기에는 매우 적은
시간만이 걸리지만, 스크립트의 명령들은 동시에 또는 임의로 이루어지지 않고, 순서대로 이루어집니다.
같은 처리기간 중에는 스크립트 명령구문이 이전의 스크립트 내용에 영향을 미치지 않습니다. 예를 들면,
10번째 줄에서 무언가가 바뀌었다면, 다음번에 스크립트가 다시 처리될 때까지 9번째 줄에는 영향을 미치지
못합니다.
이 작업 처리속도는 거의 동시에 가깝습니다.
또 한가지, 1단계에서 얻어진 실제 장치의 값의 변경을 제외하면, 1,3,4단계에서는 변수들의 값이
변하지 않습니다. 2단계 동안에서만 스크립트 명령구문의 결과가 바뀝니다.
A Simple Script [간단한 스크립트 예]
간단한 스크립트 예제가 조금 이해에 도움이 될 수 있을 것 같습니다. 어떤 이유로 해서 하나의 조이스틱에
맵을 만들려고 한다고 해보겠습니다. 조이스틱 2번 버튼이 해제되었을 때 Control Manager
Device 1이 눌러지고 그 반대도 가능하도록 하고 싶다고 해 봅니다.
단순한 예이지만, 데이터가 시스템에서 어떻게 움직이는지를 보여줍니다.
위의 내용에 따라 스크립트를 만들면 이런 식으로 될 것입니다:
SCRIPT
CMS.B1 = NOT JS1.B2;
ENDSCRIPT
스크립트는 실제로는 SCRIPT와 ENDSCRIPT 명령줄 사이의 한 줄로 이루어집니다. 명령구문의
내용은 단순히 CMS.B1(CMS Controls의 첫 번째 버튼)을 JS1.B2(조이스틱의 2번 버튼)의
반대로 설정한다는 것입니다.
루프가 실행될 때마다, JS1.B2의 상태가 체크되고 그 반대값이 CMS.B1에 전송됩니다.
CMS.B1은 Windows에서 자동으로 인식되는 장치가 아니므로, GUI에서 CMS Control의
1번 버튼을 선택해놓아야 합니다. 그 버튼을 DX Mode로 설정하고 CM Device 1, Button
2로 지정합니다.
여러 개의 장치들이 그 버튼을 제어하지 않도록 하기 위해 GUI에서 이전에 있던 CM Device
1, Button 2의 지정값을 삭제할 수 있습니다.
맵을 설정하고 다운로드하면, 조이스틱의 2번 버튼을 해제하면 Button 2가 눌러지고 조이스틱 버튼을
누르면 Button 2가 해제되는 것으로 작동하게 됩니다.
Script Definition [스크립트 정의]
맵을 새로 만들면, Control Manager는 항상 그에 포함된 스크립트 파일을 만듭니다. 스크립트
파일은 텍스트 파일입니다. 맵 파일과 파일명은 같지만, 확장자는 “.MAP”이 아니라 “.CMS”입니다.
스크립트는 처음에는 비어있고, 스크립트의 시작과 끝을 알리는 명령구문만 있습니다. 빈 스크립트는 다음과
같습니다:
SCRIPT
ENDSCRIPT
빈 스크립트는 아무런 기능도 하지 않습니다. SCRIPT와 ENDSCRIPT 명령구문 사이에 실행할
동작을 정의하는 스트립트 명령구문을 입력해야 합니다.
그렇지 않으면, 맵에서 실행되는 동작들은 실제 장치와 GUI에서 정의한 것에 따르게 됩니다
SCRIPT와 ENDSCRIPT 사이에 들어갈 기능들은 다음 몇 개의 장에서 다룹니다. 그 전에, 몇가지
주의해야 할 사항이 있습니다.
Case Sensitivity [대소문자 구분]
CMS 스크립트 언어는 대소문자 구분을 하지 않으며, “SCRIPT”는 ‘script”나 “ScRiPt”를
똑같이 인식합니다. 마찬가지로 “JS1.A1”은 “js1.a1”과 같습니다. 읽기 좋도록 대소문자를
구별해서 쓰는 것도 괜찮습니다. 예를 들면, “EXITCASE”나 “exitcase”라고 쓰지 않고
“ExitCase”라고 쓰는 것 등입니다. 파일에 입력된 무엇이든지 대소문자 구분 없이 같은 결과가
출력됩니다.
Comments [주석 달기]
Comment(주석)는 스크립트의 기능을 설명해주는 표시입니다. 꼭 필요하지는 않으며 스크립트의 기능에
영향을 미치지도 않습니다. 스크립트의 어느 곳에나 쓸 수 있습니다. Comment는 “//” 기호를
앞에 붙여 표시합니다. “//”으로 시작하는 문장은 그 줄의 끝까지 적용되는 것으로 간주됩니다. 예를
들면:
// This is a comment.
Conment는 꼭 필요한 것은 아니지만, 사용하는 것이 좋습니다. 오래간만에 스크립트 작업을 해서
스크립트에 어떤 기능을 넣었었는지 잘 모를 때 도움이 되며, 간단한 주석을 붙이기만 해도 크게 도움이
됩니다.
Semicolons [세미콜론]
대부분의 스크립트 명령구문은 그 줄의 실제 기능 문장의 끝에 세미콜론이 들어갑니다. 순환 제어(Flow-control)
명령구문과 몇가지 다른 기능들에서는 이 규칙에 예외가 생기는데, 이는 적당한 부분에서 설명하겠습니다.
세미콜론은 comment 부분의 앞에 들어가야 하며, 그렇지 않으면 comment의 일부로 간주됩니다.
보기
CMS.A1 = JS1.A1; // Copy Joystick
1 X Axis to CMS Axis 1
“//”로 시작되는 comment 부분은 기본적으로 스크립트에서 없는 것과 마찬가지라는 점을 기억하십시오.
Assignment statement [지정 명령구문]
스크립트에서 가장 단순하면서도 흔히 쓰이는 작업이 변수의 값을 할당하는 것입니다. 이 작업은 “=”를
써서 이루어지며, 수학 등식처럼 쓰입니다. 예를 들면:
CMS.A1 = JS1.A2;
여기서는 CMS의 1번 축이 JS1 장치의 2번 축(Y축)의 현재 값과 같아지게 됩니다. 마찬가지로(비트값의
경우):
CMS.B1 = JS1.B5;
여기서는 CMS Controls의 1번 버튼이 JS1 장치의 5번 버튼의 상태와 같아집니다.
“=” 왼쪽의 변수는 설정할 수 있는 변수라야 합니다. 여기에는 고유 변수(built-in variables)와
CMS 변수들이 포함됩니다. 스크립트로는 실제 장치의 값을 바꿀 수 없기 때문에, “=”의 왼쪽에 JSx
변수를 넣을 수는 없습니다.
“=”의 오른쪽에는 적당한 식을 넣을 수 있습니다. 여기에는 수식 연산자, 논리 연산자, 괄호, 기타
등등 필요한 어떤 변수든 넣을 수 있습니다. 예로:
CMS.A1 = JS1.A1 + JS1.A2 + 10;
CMS.B1 = (JS1.B5 OR JS1.B6) AND NOT (JS1.B6 OR JS2.B7);
식이 “;”로 끝나는 것에 주의하십시오. 이 기호는 모든 지정 명령구문에 들어가야 합니다. 다른 종류의
명령구문은 나중에 설명하겠으나, 다른 경우들에서는 “;” 기호가 필요할 때도 있고 그렇지 않을 때도
있습니다.
이 내용은 각각의 명령구문 부분에서 기능과 함께 설명합니다. 보통은, “;”는 필요하지 않은 곳에
사용하더라도 문제가 없으므로, 필요 여부를 잘 모르겠으면 구문의 끝에 넣어주십시오
Arithmetic Comparisons [부등식]
논리식에는 부등호를 쓸 수 있습니다. 논리식은 TRUE와 FALSE로 이루어집니다. 사용할 수 있는
부등호는 여섯 개가 있습니다.
논리 연산자와 마찬가지로, 텍스트와 기호 모두를 사용할 수 있으며, 다음과 같습니다.
| Less Than (미만) |
"LT" 또는 "<" |
| Less Than or Equal To (이하) |
"LE" 또는 "<=" |
| Equal To (같다) |
"EQ" 또는 "==" ("="를 두번
씀) |
| Greater Than or Equal To (이상) |
"GE" 또는 ">=" |
| Greater Than (보다 크다) |
"GT" 또는 "<" |
| Not Equal To (같지 않다) |
"NE" 또는 "!=" |
부등호임을 나타내려면, 대괄호로 묶습니다. 그러면 언제든 비트 변수로 인식이 됩니다. 부등식은 다음과
같은 형태입니다:
[ JS1.A1 > JS2.A1 ]
이것은 JS1.A1이 JS2.A1보다 크면 TRUE라는 뜻입니다.
부등식에 괄호가 있더라도, 부등식은 대괄호 안에 있어야 한다는 것이 중요합니다. 이는 IF/THRN
명령문(나중에 설명합니다)과 마찬가지입니다.
부등식이 쓰이는 경우에는 몇 가지가 있습니다. 예를 들면, 스로틀이 일정 위치 이상에 있을 때 WEP을
활성화하기 위한 경우가 될 수 있습니다.
축값은 0에서부터 255까지이고, 최대 스로틀 위치는 내부적으로는 최소값에 해당하며, 스로틀은 JS1.A3이라는
점을 기억하십시오. 다음의 예와 같이 쓸 수 있습니다:
SCRIPT
CMS.B1 = [JS1.A3 < 25];
ENDSCRIPT
이렇게 하면 JS1.A3이 90% 이상의 위치일 때 CMS.B1이 ON 상태가 됩니다. 그리고, WEP을
제어하는 키값을 전송하거나 DX 버튼을 활성화하게끔 GUI에서 CMS1.B1 버튼을 프로그래밍합니다.
Conditional Statements [조건 명령구문]
현재의 축 값과 버튼 변수에 따라 일정한 조건이 부합되면 코드의 한 블록을 실행하고 그렇지 않다면 다른
블록을 실행하게 해주도록 스크립트의 순환을 제어하는 형식이 몇 가지 있습니다.
IF/THEN
가장 기본적인 것이 IF/THEN 블록입니다. 이는 다음과 같은 제어법을 가집니다:
IF 어떤 조건이 충족되면 THEN 어떤 작업을 실행함.
IF/THEN 명령구문은 구문 끝에 세미콜론을 필요로 하지 않습니다.
예를 들어, JS1.B4가 ON 상태일 때에만 무언가를 하려면, 스크립트의 한 부분에 다음과 같이
써넣습니다:
IF( JS1.B4 ) THEN
// Do something
ENDIF
여기서는 JS1.B4가 TRUE(누른 상태)이면 THEN과 ENDIF 사이의 명령구문(들)이 실행됩니다.
JS1.B4가 FALSE(해제된 상태)이면, 스크립트의 그 부분은 건너뛰어집니다.
IF 구문의 값에는 복잡한 식이 쓰일 수도 있습니다. 예를 들면, JS1의 1번과 2번 버튼이 동시에
눌러져 있을 때 한 블록의 구문을 실행하려면, 다음과 같이 스크립트를 만듭니다:
IF( JS1.B1 AND JS1.B2 ) THEN
// Do something
ENDIF
IF/THEN/ELSE
식의 결과에 따라 둘 중 하나의 명령구문 그룹을 실행하게 하는 IF/THEN/ELSE 형식도 있습니다.
이 기능은 위에 설명한 IF/THEN과 비슷하지만 IF 구문이 FALSE가 되었을 때 실행할 스크립트
영역이 주어집니다. IF/THEN 구문과 같이, 끝에 세미콜론을 붙이지 않습니다.
예를 들어, JS1.B4가 눌려있을 때 스크립트의 한 부분을 실행하고 그렇지 않을 때는 다른 부분을
실행하고자 한다면, 다음과 같이 써넣습니다:
IF( JS1.B4 ) THEN
// Do something here if JS1.B4 is TRUE
ELSE
// Do something here if JS1.B4 is FALSE
ENDIF
Nesting IF/THEN and IF/THEN/ELSE
[중복된 IF/THEN과 IF/THEN/ELSE 구문]
IF/THEN과 IF/THEN/ELSE 부분은 “중복”될 수 있습니다. 즉, IF나 ELSE절 안에
또 다른 IF절이 들어갈 수 있습니다:
IF( JS1.B4 ) THEN
IF( JS1.B5 ) THEN
// Do thing #1
ELSE
// Do thing #2
ENDIF
ELSE
IF( JS1.B6 ) THEN
// Do thing #3
ELSE
// Do thing #4
ENDIF
ENDIF
Sequences [순열]
CMS에서 인식하는 또 다른 순환 제어 방식은 “SEQUENCE(순열)”입니다. 순열은 “SEQUENCE”라는
명령어로 시작해서 “ENDSEQUENCE”라는 명령어로 끝납니다.
이것은 기본적으로 스크립트의 독립된 한 부분의 작업(event)의 순서를 정해서 전체 스크립트 내에서
실행하게끔 해주는 독특한 방법입니다. 순열은 조건에 맞기만 하면 스크립트의 각 주기마다 순열의 구문
순서대로 실행됩니다.
순열이 그 주기에서 더 이상 실행될 수 없는 지점에 이르면 버튼을 클릭해야 하며, 그러면 그 순열 다음
위치의 스크립트가 실행됩니다.
그리고 다음 순서에는 순열이 멈추었던 위치로 가게 됩니다. 순열이 멈추었던 조건이 되면, 버튼을 눌러야
했다는 것이 표시 되고 그 지점에서부터 다시 순열이 멈출 때까지 계속 진행됩니다. 처음의 순열 중지
조건을 두 번째 진행과정에서 만나지 않는다면, 순열이 건너뛰어지고 다음 주기가 실행됩니다.
순열은 약간의 예외를 제외하면 주 스크립트에서 쓰는 대부분의 구문을 포함할 수 있습니다순열 내에서는
SELECT 블록을 사용할 수 없습니다.
기본적인 기능 이외에, SEQUENCE 안에서만 쓸 수 있는 세 가지의 특수한 기능이 있습니다.
이 기능들은 WAIT, WHILE, DELAY 구문입니다.
WAIT and WHILE
WAIT 구문과 WHILE 구문은 주어진 조건이 TRUE가 될 때까지 순열이 정지한다는 점에서 서로
매우 비슷합니다. 둘의 차이점은, WAIT 구문에서는 FALSE에서 TRUE로 바뀔 질문식을 필요로
하는데 비해, WHILE 구문은 실행중에 구문이 TRUE인지를 체크하기만 한다는 것입니다.
이를 좀더 설명하기 위해, 다음의 두 순열을 비교해보겠습니다:
// Sequence 1
//
SEQUENCE
WHILE( JS1.B1 );
B1 = TRUE;
DELAY( 10 );
B1 = FALSE;
DELAY( 10 );
ENDSEQUENCE
// Sequence 2
//
SEQUENCE
WAIT( JS1.B1 );
B1 = TRUE;
DELAY( 10 );
B1 = FALSE;
DELAY( 10 );
ENDSEQUENCE
첫 번째 순열에서는, JS1.B1을 누르고 있을 때 순열이 계속 실행됩니다. B1 비트값은 JS1.B1이
눌려있는 동안 ON 상태가 됩니다.
두 번째 순열에서는, JS1.B1이 처음 닫혔을 때 순열이 한번 실행됩니다. 순열이 다시 실행되려면
JS1.B1을 떼었다 다시 눌러야 합니다. JS1.B1을 한번 누를 때마다 B1값은 한번 TRUE가
되었다가 FALSE로 바뀝니다.
DELAY
DELAY 구문은 미리 정해진 시간 동안 순열을 잠시 정지시킵니다. DELAY 값은 순열 주기가 중지되는
키값 반복 시간(Character-time)을 나타냅니다. 키값 반복 시간은 Control Manager
GUI의 Program Setting 탭에서 정한 “Character Rate(키값 반복 속도)”와
대충 비슷합니다.
기본값인 50은 delay 값이 한단계 늘어나면 delay 시간이 50밀리초(0.5초) 늘어난다는
것을 뜻합니다.
DELAY 순열은 다음의 예와 같습니다:
// Wait until Button 4 on JS1 is
pressed, then flash Button 1 on the
// CMS Controls 2 times.
//
SEQUENCE
WAIT( JS1.B4 ); // Wait for the JS1 button to get pressed
CMS.B1 = TRUE; // Turn on the CMS button
DELAY( 10 ); // Wait about half a second
CMS.B1 = FALSE; // Turn off the CMS button
DELAY( 10 ); // Wait about half a second
CMS.B1 = TRUE; // Turn on the CMS button
DELAY( 10 ); // Wait about half a second
CMS.B1 = FALSE; // Turn off the CMS Button
ENDSEQUENCE
JS1.B4를 누를 때마다 CMS.B1이 키값 반복속도에 따라서 약 0.5초 간격으로 두 번 켜졌다
꺼집니다.
Scripting
Reference [스크립트 참고] -- PART 2
Nesting [겹치기]
SEQUENCE/ENDSEQUENCE 블록은 IF/THEN과 IF/THEN/ELSE 블록 안에 겹쳐
쓸 수 있습니다. IF의 결과에 따라서 그 블록이 건너뛰어지면 이들 블록의 안에 있는 순열은 이미 시작되었던
것이라고 해도 끝까지 실행되지 않는다는 점을 기억하십시오.
쉽게 말하면 IF 절이 중지되면 그 안에 있는 순열도 정지됩니다. 이는 상황에 따라서 도움이 될 수도
있고 그렇지 않을 수도 있습니다.
Logical Device [논리 장치]
논리 장치는 타이머 등에 쓰입니다. 논리 장치는 “D1”에서 “D256”까지의 256개가 가용합니다.
장치 기능이 실행될 때 지정자가 할당됩니다. 그 다음에 그 기능의 상태에 따라 ID가 쓰입니다.
네 가지 종류의 장치를 사용할 수 있습니다. 세 가지는 타이머이고, 나머지는 주어진 조건이 TRUE일
때 짧은 펄스를 생성하는데 쓰입니다.
Timer Device [타이머 장치]
타이머 장치는 하나의 비트 값(식으로 된)으로 제어됩니다. CMS가 인식하는 타이머에는 세 가지 종류가
있습니다. 타이머들은 시간 계산 기능을 제공하는데 가장 많이 쓰이며, 필요하다면 다른 장치와 결합되어
더욱 정교한 시간차 순열을 만들어 낼 수도 있습니다.
On Delay Timer
첫 번째 설명할 타이머는 On-Delay 타이머입니다. 이 타이머는 타이머를 제어하는 식(입력값)이
TRUE이면 관련된 장치의 변수를 지정된 시간동안 TRUE로 설정합니다.
장치 변수가 일단 설정되면, 입력값이 FALSE가 될 때까지 그 값이 유지됩니다. 그러면 장치 변수값이
FALSE가 되고 타이머가 초기화됩니다. 어떤 변경치가 있더라도 시간 지연값이 초기화됩니다.
예:
TIMER( ONDELAY, D5, 10 ) = JS1.B2;
첫 번째의 변수(ONDELAY)는 타이머의 종류를 정합니다. 두 번째 변수(D5)는 스크립트에서
이 타이머를 인식하게끔 하기 위한 장치 변수를 지정합니다. 세 번째 변수(10)는 GUI Program
Setting 탭의 Character Rate 설정에 기초해서 단위 시간을 정합니다.
JS1.B2는 입력장치입니다. 이것이 TRUE이면, 시간이 시작됩니다. JS1.B2는 최소한 정해진
시간 동안 값이 유지되며, 그 다음 D5가 TRUE가 되어 JS1.B2가 해제될 때까지 TRUE로 유지됩니다.
정해진 시간 이전에 JS1.B2가 해제되면, D5는 TRUE가 되지 않습니다.
타이머를 제대로 쓰려면, 스크립트의 어느 부분에 D5를 지정해주야 합니다. 예를 들면:
SCRIPT
TIMER( ONDELAY, D5, 10 ) = JS1.B2;
CMS.B1 = D5;
ENDSCRIPT
이렇게 하면 CMS.B1이 10 단위시간 동안 내지 JS1.B2가 눌려있는 상태로 약 0.5초 후에
켜집니다. 정해진 시간 이전에 JS1.B2가 해제되면 타이머가 초기화되고 CMS.B1에 설정값이 적용되지
않습니다.
Off Delay Timer
두 번째의 타이머 종류는 Off-Delay입니다. Off Delay 타이머는, 입력값이 TRUE이고
계속 TRUE인 동안 장치 변수가 즉시 TRUE로 설정됩니다. 입력값이 FALSE가 되면, 일정한 시간
지연값이 시작됩니다. 지연 시간이 끝나면 장치 변수는 FALSE가 됩니다.
장치 변수가 FALSE가 되도록 정해진 시간 이전에 입력값이 다시 TRUE가 되면 타이머가 초기화되고,
입력값이 다시 FALSE가 되면 지연 시간이 처음부터 다시 시작됩니다.
Off-Delay의 용법은 On-Delay와 꽤 비슷합니다:
TIMER( OFFDELAY, D3, 20 ) = JS2.B3;
첫 번째 변수는 OFFDELAY 타이머라는 것을 정의하고, 두 번째 변수는 장치 변수를 지정하며,
세 번째 변수는 지연 시간의 길이를 설정합니다. 위의 예에서, JS2.B3을 누르면 D3는 즉시 TRUE가
됩니다.
D3는 JS2.B3가 해제될 때까지 계속 TRUE이며, JS2.B3가 해제되면 약 1초간의 지연 시간이
시작됩니다. 그 시간이 지나면 D3은 FALSE가 됩니다.
이 기능은 여러 가지 용도로 유용합니다. 예를 들면, 전투비행 시뮬레이션에서 트리거를 당겼을 때
건 카메라를 활성화하게끔 하고 트리거를 놓은 후 일정 시간동안 건 카메라가 돌아가게끔 할 수 있습니다.
그러자면 이런 식으로 스크립트를 만들 수 있습니다:
SCRIPT
TIMER( OFFDELAY, D1, 200 ) = JS1.B1;
CMS.B1 = D1;
ENDSCRIPT
트리거를 당기면 D1과 CMS.B1이 TRUE가 되어, 트리거를 놓은 후 약 10초 후까지 계속 TRUE가
됩니다.
단, GUI에서 Press, Release 명령어를 사용하여 CMS.B1을 눌렀을 때 “카메라 시작”에
해당하는 키값이 전송되고 CMS.B1이 해제되었을 때 “카메라 중지” 키값이 전송되도록 프로그래밍해야
합니다.
Interval Timer
세 번째 타이머는 Interval 타이머입니다. 이 타이머는 깜빡이와도 같이 입력값이 TRUE일 때
장치 변수를 계속 TRUE와 FALSE로 반복되게 합니다. 용법은 On-Delay와 Off-Delay와
비슷하지만, 다음과 같이 두 번째의 시간간격을 지정해주어야 합니다:
TIMER( INTERVAL, D7, 30, 40 ) = JS2.B4;
처음의 두 변수들은 타이머 종류와 장치 변수를 정의합니다. 나중의 두 변수는 각각 TRUE 시간과
FALSE 시간을 정의합니다. 입력값이 처음 TRUE가 되면 TRUE 타이머가 시작되고, 앞에 표시된
시간 동안 시간이 지나면 FALSE가 되며, 그 다음 뒤에 표시된 시간동안 타이머가 작동한 후 TRUE로
바뀌는 과정이 반복됩니다.
이 과정은 JS2.B4가 눌려있는 동안 계속됩니다.
이 타이머는 여러 기능에 유용합니다. 하나의 예로 “미세 트림 조종” 기능을 들어보겠습니다:
SCRIPT
TIMER( INTERVAL, D1, 20, 100 ) = JS1.B2;
TIMER( INTERVAL, D2, 20, 100 ) = JS1.B3;
CMS.B1 = D1;
CMS.B2 = D2;
ENDSCRIPT
위의 예에서는 JS1.B2가 눌려있는 동안 D1이 5초 간격으로 깜빡이고, JS1.B3이 눌려있는
동안에는 D2가 5초마다 깜빡이게 됩니다. GUI에서 CMS.B1에 “Trim Up” 키를 매핑하고
CMS.B2에 “Trim Down” 키를 매핑하면, 이 버튼들을 누르고 있는 동안 항공기의 트림이 그쪽
방향으로 느리게 조정됩니다.
Pulse Device
네 번째의 장치 종류는 “Pulse” 장치입니다. 처음에는 입력값이 TRUE일 때 이 장치의 장치
변수가 TRUE가 됩니다. 스크립트의 다음 주기가 실행될 때 장치 변수는 FALSE가 되고 계속 FALSE
상태로 남아있다가 입력값이 FALSE가 되면 다시 TRUE로 바뀝니다.
Pulse 기능은 스크립트의 다른 부분에서 어떤 작업의 실행을 인식할 필요가 있을 때 쓸모가 있지만,
작업 표시가 계속 ON 상태로 남아있으면 문제가 발생할 수도 있습니다. Pulse 장치를 인식하게 하려면,
다음과 같은 코드를 넣습니다:
PULSE( D2 ) = B1;
위의 예에서, B1이 처음 TRUE로 인식된 스크립트의 주기동안 D2는 TRUE 상태가 됩니다. 스크립트의
다음 주기에서는 FLASE로 되돌아갑니다.
Pulse 장치는 키값을 직접 전송하는데는 적당하지 않습니다. 키값 프로세서가 값을 정확히 인식하기에는
Pulse 장치의 인식 주기가 너무 짧습니다.
이런 문제가 있다면, Off-Delay Timer를 사용하는 것이 좋습니다:
SCRIPT
PULSE( D2 ) = B1;
TIMER( OFFDELAY, D3, 10 ) = D2;
CMS.B1 = D3;
ENDSCRIPT
이 예에서는, D2 트리거의 짧은 펄스로 D3에 Off-Delay가 적용됩니다. D3이 TRUE가
되고 D2가 다음 주기에서 FLASE가 되면, D3의 타이머가 작동하기 시작합니다. Off-Delay는
키값 반복속도와 직접 연동되므로, 키값 프로세서가 값을 충분히 인식할 수 있을 만큼의 길이로 변수값이
유지됩니다.
동작이 인식되지 못하면, Program Settings에서 Character Rate를 늘리거나 Off-Delay
구문의 시간 값을 늘려보십시오.
Scale Function [스케일 기능]
“SCALE” 기능은 CMS controls와 실제 컨트롤러로 비행할 때 스케일 변수를 설정하는데 쓰입니다.
이 기능은 “Centered” 표시를 제외하면 다른 GUI의 모든 스케일 변수 설정들보다 우선합니다.
여기에는 데드존(deadzone), 민감도(sensitivity), 입력값 곡선(gain curve)
등등이 포함됩니다. 보통은 Axis Dialog에서 설정됩니다. SCALE 기능의 결과값은 다른 SCLASE
기능이 실행될 때까지 적용됩니다.
SCALE 구문은 다음과 같습니다:
SCALE( CMS.A1, 100, 5, GAIN6 );
첫 번째 변수는 스케일 변수가 적용될 축을 정하며, 여기서는 CMS.A1입니다. 두 번째 변수는
“Sensitivity(민감도)”값이며, -100에서 100까지의 값을 퍼센트로 입력할 수 있습니다.
세 번째 변수는 DeadZone 변수이며 이 역시 퍼센트 값입니다. 마지막 값은 GAIN 값이며, GAIN1에서
GAIN11까지를 쓸 수 있습니다.
이들은 각각 GUI에서 적용할 수 있는 11개의 gain(입력값 조정) 설정과 일치합니다. GAIN6은
수평이며, 다른 값들은 GUI의 Gain 화면의 왼쪽 아래에서 오른쪽 위로 올라가는 직선입니다. GAIN1에서
GAIN5까지는 중앙쪽이 덜 민감하고 가장자리쪽이 더 민감합니다. GAIN7에서 GAIN11까지는 그
반대로, 중앙쪽이 더 민감하고 바깥쪽이 덜 민감합니다.
SCALE 설정을 이용하면 여러 모드를 사용하는 프로그램에서 세 가지 모든 모드의 gain 값을 설정할
수 있습니다. 컨트롤러의 동작(보통의 일반적인 경우)에 상관 없이 특정한 반응이 필요하다면 간단히 GUI에서
설정할 수 있습니다.
SCALE 구문은 순항중에는 보통의 조종을 하고 착륙시에는 미세조종을 하고 싶을 때와 같이 비행중에
스틱의 반응을 바꾸고자 할 때에만 필요합니다. 예제는 Sample Scripts 부분을 보십시오.
Select Function [선택 기능]
SELECT 기능은 현재의 아날로그 변수값에 기초해서 몇 가지 다른 기능들을 실행할 때 쓰입니다. 이
기능은 설명서에서 가장 복잡한 부분이지만, 매우 쓸모가 있습니다. 기본적으로는 아날로그 입력값을 적용하고,
그 값의 범위를 판단해서 그 영역에 지정된 작업을 실행하는 것입니다.
이 구문은 대부분의 프로그래밍 언어에서 사용할 수 있는 “case”나 switch” 구문의 수정판으로
이해할 수 있습니다. SELECT 기능은 SEQUENCE 블록 안에서는 사용할 수 없다는 것을 주의해
주십시오.
Select 블록의 기본 형식은 다음과 같습니다:
SELECT( INPUTVALUE, TYPE ) OF
// CASE Definitions go here
ENDSELECT
“INPUTVALUE”는 블록을 제어하는 아날로그 값이며, 단일 변수나 수학식이 쓰일 수 있습니다.
“TYPE”는 “POSITION”이나 “RANGE”둘 중 어느 것을 사용해도 되며, select 구문의
작동법을 제어합니다.
기본적으로, TYPE가 “POSITION”으로 되어 있으면, Select 구문은 현재 영역을 벗어나면서
정해진 것을 실행하고 새로운 영역으로 들어가면서 정해진 것을 실행함으로써 현재 입력값의 영역 변화에
반응합니다.
TYPE가 “RANGE”로 선택되어있다면, Select 구문은 현재 영역에서 새 영역으로 움직임에
따라 반응하는 것은 같지만, 각 영역 사이의 모든 영역들이 실행됩니다.
예를 들어 입력값이 1번 영역에서 3번 영역으로 곧바로 바뀐다면, POSITION 형식에서는 1번
영역을 빠져나가 3번 영역으로 들어가는 것으로 인식합니다.
반면, “RANGE” 형식에서는, 1번 영역을 나가서 2번 영역으로 들어가고, 다시 2번 영역을 나가서
3번 영역으로 들어가는 것으로 인식됩니다.
물론, “POSITION” 형식에서는 게임중 입력값의 움직임이 어느정도 빠르게 이루어지면 2번 영역을
인식하지 못하고 3번 영역으로 지나치게 되므로, 움직임이 상대적으로 느릴수록 정확해집니다.
Select 구문의 다음에 오는 단어는 “OF”입니다.
이 단어의 뒤에는 “CASE” 구문들이 따라오며, 그 각각은 영역 한계와 그 영역을 들어가고 나올
때 실행될 동작들을 정의합니다. 이 구문들은 “CASE”로 시작되며, 양수의 상수와 콜론 표시가 되에
옵니다. 영역 진입 행동은 항상 정해야 합니다.
“EXITCASE”라는 단어로 진입과 이탈 행동을 분리함으로써 영역 이탈시의 행동도 포함시킬 수 있지만,
EXITCASE는 선택사항입니다. 모든 경우의 마지막에는 “BREAK” 구문을 붙여 표시합니다.
Select 블록의 예는 다음과 같습니다:
SELECT( JS1.A1, RANGE ) OF
CASE 0:
B1 = TRUE;
EXITCASE:
B1 = FALSE;
BREAK;
CASE 64:
B2 = TRUE;
EXITCASE:
B2 = FALSE;
BREAK;
CASE 128:
B3 = TRUE;
EXITCASE:
B3 = FALSE;
BREAK;
CASE 192:
B4 = TRUE;
EXITCASE:
B4 = FALSE;
BREAK;
ENDSELECT
여기서는 JS1.A1 축이 4개의 영역으로 나뉩니다. 표준 축 영역(0~255)이 JS1.A1에
적용되며, 이 영역이 64, 128, 192의 값위치에서 동일한 크기로 4등분됩니다. 컨트롤이 이 영역을
지나면, 컨트롤의 움직임에 따라 맨 아래에서부터 B1이 켜지고, 그 다음 B2, B3, 마지막으로 맨
위에서 B4가 켜집니다.
지정된 영역은 한 값에서 다른 값까지라는 점을 주의하십시오. 즉, “CASE” 다음의 값은 영역의
아래쪽 한계이며, 위쪽 한계는 한 단계 높은 CASE 값의 -1까지 입니다.
가장 높은 값의 영역은 그 영역의 최소값보다 높은 모든 값입니다. 위의 예에서는, JS1.A1의 191
이상의 모든 값들이 4번째 영역이 됩니다.
가장 낮은 영역의 CASE 구문이 0보다 크다면, 0에서 최소 case값까지는 “아무것도 실행되지
않는” 영역이 됩니다. 입력값이 정의된 가장 작은 값 영역보다 작자면, 그 영역으로 들어가고 나갈 때
아무 것도 실행되지 않습니다.
각각의 case들은 EXITCASE:를 가집니다. 입력값이 그 영역에 들어갈 때 CASE와 EXITCASE
구문 사이의 코드가 실행됩니다. 아날로그 값이 일정한 영역을 벗어나면 EXITCASE:와 BREAK
구문 사이의 코드가 실행됩니다.
CMS는 영역이 바뀌는 동안 키값 프로세서와의 동시성을 유지하므로, EXITCASE 구문의 키값은
새 영역의 CASE 구문보다 먼저 전송됩니다.
위에 설명한 바와 같이, EXITCASE는 선택사항입니다. Case는 다음과 같이 쓸 수도 있습니다:
CASE 100:
B1 = TRUE;
BREAK
이 경우에는, 입력변수가 처음 100을 넘으면 B1이 설정됩니다. 단, 이 경우에는 B1을 FALSE로
만드는 설정이 버튼 등에 의해서 이루어져야 하며, 그렇지 않으면 계속 B1이 ON 상태로 있게 됩니다.
Statement in CASE Definitions [CASE
정의 내의 구문]
CASE 정의 내에서는 문제 발생을 방지하기 위해 몇 가지 종류의 구문만을 사용할 수 있습니다. 사용할
수 있는 구문들에는 IF/THEN, IF,THEN/ELSE, SCALE 구문들과 기본 지정 작업 (“=”)
등이 있습니다. 순열은 사용할 수 없으며, 장치 이름은 완벽히 인식 가능하지만 장치 정의도 사용할 수
없습니다.
그렇지만, Select 블록에서 이 항목들을 제어할 수는 있습니다. 다음의 예에서는, js1.a1의
값이 128(중앙)보다 크면 순열이 실행됩니다:
SCRIPT
// First, set it up so B1 is TRUE
when we're above center.
//
SELECT( JS1.A1, POSITION ) OF
CASE 0:
BREAK;
CASE 128:
B1 = TRUE;
EXITCASE:
B1 = FALSE;
BREAK;
ENDSELECT
// Now run a sequence based on B1
(We're not in the
// select block now so anything goes);
//
SEQUENCE
WAIT( B1 ); // Wait for b1
CMS.B1 = TRUE; // Turn on CMS.B1
DELAY( 20 ); // Leave it on for about a second
CMS.B1 = FALSE; // Turn it off
ENDSEQUENCE
ENDSCRIPT
이 기능으로 무엇을 할 수 있는 지를 간단하게만 설명했지만, 이 기능으로 할 수 있는 일들과 기능을
적합하게 조합하는 여러 방법들이 있을 수 있습니다.
Setting the Mapper Mode [매퍼 모드 설정]
스크립트에서 현재의 Mapper Mode를 설정할 수 있습니다. 그러자면, CURRENTMODE 변수를
원하는 모드로 설정하면 됩니다:
CURRENTMODE = MODE2;
이렇게 하면, 컨트롤러에 Mode 제어 기능이 없을 때나 장치의 모드 제어 버튼이 아니라 일반 버튼으로
모드를 제어하고자 할 때 스크립트를 이용하여 매퍼 모드를 제어할 수 있습니다. 단, CMS에서 모드를
설정할 때에는 모드 변경 기능이 있는 실제 장치의 모드 표시등이 현재 모드에 맞게 표시되지 않는다는
점에 유의하십시오.
장치의 모드 표시등은 장치의 Mode 버튼을 사용하였을 때에만 정상적으로 표시됩니다.
사용할 수 있는 모드는 MODE1, MODE2, MODE3이며, 숫자값 0,1,2를 쓸 수도 있습니다.
그러면 모드 변경 스위치 프로그래밍을 좀더 쉽게 할 수 있습니다. 구체적인 예제와 사용법은 Sample
Scripts 부분을 보십시오.
CMS에서 Mode를 제어하는 맵을 만들면, Control Manager GUI의 “Program
Setting”으로 가서 “Mode Control”을 CMS Controls”로 바꾸어야 합니다.
그러면 Dialog Pane에 Mode 2와 Mode 3 탭이 활성화되는 대신, FighterStick이나
ProThrottle의 Mode 세팅 기능은 비활성화됩니다.
각 모드의 설명은 Mapper Modes 부분을 보십시오.
Miscellaneous
Topics [기타 사항]
Programming
Tips [프로그래밍 팁]
스크립트 작업을 할 때의 몇 가지 팁을 알려드립니다. 프로그래밍하는 법은 아니지만, 스크립트를 더 쉽게
만들고 테스트할 수 있으며, 나타날 수 있는 문제들을 해결하는데 도움이 되는 방법들입니다.
팁 #1 한번에 한 가지의 기능만을 만들 것
한번에 스크립트에 한가지 기능만을 만들고 최소한의 맵을 만들어 기능이 제대로 작동하는지 확인해봅니다.
임시로 “작동하는 맵”을 만들어 특정한 기능이 작동하는지를 확인하고 와 그 기능을 GUI에서 할당해봅니다.
그러면 테스트용으로 다운로드하는 시간이 절약되며, 수정하기도 쉽습니다.
만들어본 기능이 제대로 작동하면, 실제로 사용할 맵에 붙여넣기를 해서 최종적인 테스트를 합니다.
팁 #2 스크립트 체크 버튼을 기억할 것
스크립트 파일을 다운로드하기 전에 CMS 에디터에서 Script Check 버튼을 이용하는 습관을 들이십시오.
그러면 오타와 오작동을 빨리 찾아낼 수 있고, 시간과 다시 편집작업을 해야 하는 노력이 절약됩니다.
팁 #3 맵을 실행하기 전에 꼭 저장할 것
이는 버그 수정을 할 때 매우 중요한 사항입니다. 맵을 실행해서 키값이 산출되거나 오작동이 되면, 맵이
바뀌어버릴 수도 있습니다. 저장을 먼저 하십시오. 그러면 문제가 생기더라도 작업내용이 망쳐지지 않습니다.
팁 #4 우선 “보이게” 할 것
처음 어떤 기능을 만들 때 펑션키(F1, F2 등)와 같은 “보이지 않는” 키값을 사용하는 것은 피하고,
그대신 “a”나 “b”처럼 보이는 키값으로 만드십시오. 오작동이 있을 때 기본 키들은 Windows
메뉴나 기능이 실행되는 등의 문제를 발생시킬 위험이 더 적습니다.
또한 키값을 메모장이나 다른 텍스트 편집기로 확인하기도 쉽습니다. 키테스트 유틸리티에서는 키를 누르고
떼는 것이 보이지만, 다른 Windows 프로그램에서는 보일 수도 있고 보이지 않을 수도 있습니다.
메모장을 이용하면 키값 작동상태를 잘 알아볼 수 있어서, 게임에서 어떻게 작동할지를 더 잘 확인할
수 있습니다. 메모장에서 원하는 대로 키값이 나온다면, 스크립트로 돌아가서 실제로 원하는 키로 바꾸어주면
됩니다.
팁 #5 처음의 테스트에는 Keytest와 Test/Calibrate를
이용할 것
맵을 처음 테스트를 할 때는 Test/Calibrate 화면과 Keytest 유틸리티를 이용하십시오.
축, 버튼, 키값을 보면 스크립트의 잘못된 부분을 쉽게 알 수 있습니다. 이런 유틸리티들을 이용하면
Control Manager에서 빠져나가서 게임을 실행하는 것보다 훨씬 빠릅니다.
최종적으로는 게임에서 테스트해야 하지만, GUI에서 테스트를 하면 Control Manager와 게임을
왔다갔다 하는 수고를 덜 수 있습니다. 운이 좋다면, 실제로 게임에 들어갔을 때 수정할 사항이 별로
없을 것입니다.
팁 #6 스크립트의 수정
특별히 할 일이 없이 스크립트를 열었다면, 디버깅의 첫 번째 규칙 ? “하려고 했었던 것만을 하라”
? 을 명심하십시오.
CMS는 “생각”을 하지 않으며, 스크립트에서 지시한 것만을 실행합니다. CMS에서 어떻게 실행되는지를
보고, 스크립트를 본 후, 어디에서 어떤 문제가 실행되는지를 확인해보십시오. 보통은 작동하는 부분의
스크립트 위치를 찾는 것이 어렵지 않으며, 그 부분부터 보면 됩니다.
팁 #7 실행되고 있는 잘못된 스크립트는 종료할 것
CMS에서는 스크립트를 만드는 것이 가능하며, 맵이 실행되고 있을 때에는 이것이 문제가 될 수 있습니다.
보통은 스크립트를 닫는 작동은 나타나지 않기 때문에 키가 눌려있는 상태가 발생하는 것 정도 이상의 오작동은
별로 없지만, 그것이 약간의 문제를 발생시킬 수는 있습니다. 그럴 때를 대비한 약간의 팁을 말씀 드리자면:
1. GUI에서 수정작업을 하고 있다면, Direct
Mode 버튼을 클릭해서 맵을 닫을 수 있습니다.
2. 어떤 키에 문제가 있는지 안다면, 키보드로
그 키를 타이핑해서 키값의 오작동을 멈출 수 있습니다.
3. 키값의 오작동으로 인하여 Windows에
문제가 발생하면 조금 더 어렵게 됩니다. 마우스를 사용할 수 있다면, 역시 Direct Mode로 가서
맵을 닫을 수 있습니다.
키값 오작동으로 인해서 시스템이 어떤 동작을 한다면 문제가 될 수 있습니다. 일례로 TAB 키가 눌려있는
상태가 되면, 커서가 데스크탑 주위를 계속 돌게 되며, 마우스를 사용하기 힘들어집니다.
그런 경우에는, CH USB 장치를 뽑으면 Control
Manager가 Direct Mode로 돌아옵니다. 장치를 뽑으면 문제가 해결될 것입니다. Mode가
바뀐 후에 장치를 다시 꽂을 수 있습니다.
어떤 문제들은 해결하기 힘들기도 합니다. 문제 해결의 주안점은 어떤 방법으로든 Control Manager를
Direct Mode로 돌려놓는 것입니다.
팁 #8 시작시의 문제 해결
Windows 시작시에 CMSart 유틸리티를 실행하도록 설정하였다면, 스크립트 수정작업시에 문제가
있는 맵을 다운로드해놓지 않도록 주의하십시오. Windows를 다시 시작할 때 맵이 자동으로 실행됩니다.
그러면 Windows 시작과 동시에 문제가 발생할 수 있습니다.
물론, CMStart를 불활성화시키거나 제대로 된 맵을 다운로드해서 문제를 해결할 수 있습니다.
스크립트 예제
#1 축 결합
이 장에는 스크립트 예제가 들어있습니다.
모든 것을 다 포함하지는 않으며 그대로 사용하기 위한 것도
아니지만, 자신만의 CMS를 만드는데 도움이 될 수 있을 것입니다.
예제중 어떤 부분들은 주석이 달려 있기 때문에 문장이 깁니다.
쉽게 읽으려면, 명령줄이 다음 줄로 넘어가서 혼란되지 않게끔 Help 창을 최대로 하십시오.
이 예제는 CMS를 이용하여 일정한 조건에서 여러 축들을 하나의 축으로 설정하는 방법을 보여줍니다.
이 예에서는 토 브레이크를 Y 축 하나로 결합합니다.
이 기능은 액셀레이터와 브레이크 페달을 별도로 지원하지 않고 센터값이 액셀과 브레이크의 기본값으로
주어지는 레이싱 시뮬레이터에서 쓸모가 있습니다.
스크립트를 시작하기 전에, 문제가 무엇인지 살펴보고, 현재 상태를 파악하고, 해결할 방법을 찾도록
합니다.
이 예제에서 유용한 사실은 모든 축들은 0에서 255까지의 범위를 가진다는 것입니다. 이것은 실제
컨트롤러에서뿐만 아니라 CMS Controls를 통해 Windows로 보내지는 값도 마찬가지입니다.
알아야 할 두 번째 사실은, ProPedal에서 왼쪽 토 브레이크는 A1 축이며 오른쪽 토 브레이크는
A2 축이라는 것입니다. Test/Calibration 화면에서 이 값들과 방향을 찾기 쉬우며, GUI에도
장치 이름이 나옵니다.
마지막으로 알아야 할 사항은 게임에서 필요한 동작입니다. 보통은 0이 최대 스로틀이고, 255가
최대 브레이크, 그리고 128이 스로틀과 브레이크 모두 작동하지 않은 상태입니다. 단, 경우에 따라
바뀔 수 있습니다.
요약하자면, 두개의 토 브레이크 축이 있고, 두 축은 놓았을 때 0과 최대로 눌렀을 때 255의
값을 가집니다. 우리가 할 일은 하나의 페달이 0에서 128까지의 값을 산출하고 다른 페달에서는 128에서
255까지의 값을 산출하도록 하는 것입니다.
이는 간단한 산수이므로, 우리가 할 일도 간단합니다.
The Script [스크립트 예문]
이 예에서 우리가 사용할 GUI의 첫 번째 Device Tab의 조종 핸들이 JS1이라고 가정합니다.
그리고 ProPedal은 GUI의 두 번째 Device Tab에 있고 JS2라고 가정합니다. 사용자
여러분의 장치가 이와 다르다면, 각자에 맞게 바꾸어주어야 합니다. 위의 가정에 따른 스크립트는 다음과
같을 것입니다:
SCRIPT
CMS.A1 = 128 + (JS2.A2/2) - (JS2.A1/2);
ENDSCRIPT
실제로는 단 한 줄짜리 스크립트입니다. 이 스크립트는 128의 센터값에서 시작되고, 한쪽 절반은 Y축
값, 그리고 다른 한쪽 절반은 X 축 값이 더해집니다.
그래서, 우리가 원하는 대로 오른쪽 토 브레이크(A2)를 누르면 128에서 255까지 값이 늘어나며,
왼쪽 토 브레이크(A1)을 누르면 최초의 128에서 0쪽으로 값이 줄어듭니다.
맵을 완성하려면, GUI에서 축 할당을 해주어야 합니다. Yoke의 X축은 CM Device 1의
X축으로 할당하고, Yoke의 Y축은 사용하지 않을 것이므로 “None”으로 할당합니다. CMS Controls의
1번 축은 CM Device 1의 Y축으로 할당합니다.
스크립트 예제
#2 맵 모드 제어
Setting the Mode 부분에서 설명한 대로, CMS의 CURRENTMODE 변수로 맵 모드를
제어할 수 있습니다. 이 예제에서는 FighterStick과 ProTrottle의 하드웨어 모드 스위치처럼
작동하는 모드 순환 스위치를 만들 것입니다.
여기서 오직 중요한 사실 한가지는 세 모드를 순환하기 위해서 CURRENTMODE 변수를 0,1,2,
그리고 다시 0으로 돌려야 한다는 것입니다.
이 예에서는 내부 아날로그 변수중의 하나인 A1을 사용해서 설정하고자 하는 모드를 기억하게끔 할 것입니다.
변수는 버튼을 한번 누를 때마다 증가하며, 변수가 2를 넘을 때는 0으로 초기화됩니다. WAIT()
기능을 이용하면 버튼을 클릭할 때까지 과정을 멈출 수 있으므로 이를 위해 순열이 가장 쉬운 방법이라고
생각됩니다.
The Script [스크립트 예문]
이 맵에서는, 맵에서 CombatStick만 인식하고 그 장치의 Button 2를 모드 변경 버튼으로
쓴다고 가정합니다. 스크립트는 다음과 같이 될 것입니다:
SCRIPT
SEQUENCE
WAIT( JS1.B2 ); // Wait here until JS1.B2 clicks
A1 = A1 + 1; // Add 1 to our Mode counter
IF( [ A1 > 2 ] ) THEN // If the value is over 2 then
A1 = 0; // set it to 0
ENDIF
CURRENTMODE = A1; // Now copy it to CURRENTMODE
ENDSEQUENCE
ENDSCRIPT
JS1.B2를 한번 클릭할 때마다 A1이 1씩 증가합니다. A1이 2를 넘으면, 다시 0이 됩니다.
그러면 값은 0, 1, 2, 0, 1, 2 등으로 순환됩니다. 그럼으로써 의도했던 대로 세 모드가 순환됩니다.
CM Device 축이나 버튼을 제어하는 것은 아니므로, 맵과 충돌이 일어나지 않도록 CombatStick의
Button 2를 빼고는 GUI에서 “None”으로 할당하도록 합니다.
스크립트 예제
#3 트림 지동 조정
이 예제는 자동 트림조정 기능입니다. 예제상에서, 직선 수평비행을 할 때까지 조이스틱을 움직입니다.
그 시점에서 그 위치로 축을 고정하는 버튼을 누릅니다. 버튼을 누르고 있으면서 조이스틱을 중앙으로 원위치
시키고 버튼을 뗍니다.
그러면 조이스틱이 중앙에 있을 때의 트림 설정이 유지되며, 조이스틱을 움직이면 그쪽으로 움직임이 주어집니다.
트림을 초기화하려면, 조이스틱을 중앙에 놓은 채로 그 버튼을 다시 누릅니다.
이 역시 간단한 산수문제입니다. 원하는 트림 위치의 값을 찾고, 그 다음에는 그 값과 조이스틱이
중앙에 있을 때의 값과의 차이를 계산합니다.
이 차이가 파악되면 실제 조이스틱 값에 이 수치를 추가하여 “트림 조정된” 값을 만들어냅니다.
The Script [스크립트 예제]
이 예제에서는 맵에서 CombatStick 한가지만 JS1로 인식하고, CombatStick의 Button
2를 “트림” 버튼으로 사용한다고 가정합니다.
스크립트는 두 단계의 과정으로 되어있습니다. 처음에는 Button 2를 눌렀을 때의 트림값을 계산하고,
그 다음에는 Button 2가 해제되면 트림값을 적용합니다. X축과 Y축의 트림값 차이를 기억하도록
각각 내부 변수 A1과 A2를 이용할 것입니다.
조이스틱의 트림값은 계속 업데이트하여 버튼이 해제되어있는 동안 계속 적용되도록 합니다. 반면, 처음
버튼을 클릭했을 때만 트림값 차이를 계산할 필요가 있습니다.
앞의 사항을 위해서는 IF/ENDIF 블록이 적당하고, 뒤의 사항에는 SEQUENCE가 적당합니다.
스크립트는 다음과 같이 될 것입니다:
SCRIPT
IF( NOT JS1.B2 ) THEN // If Button 2 is released then
CMS.A1 = JS1.A1 + A1; // add the X offset to the stick X
value
CMS.A2 = JS1.A2 + A2; // and add the Y offset to the stick
Y value
ENDIF
SEQUENCE
WAIT( JS1.B2 ); // Wait until Button 2 clicks
A1 = JS1.A1 - 128; // Calculate the X offset and save it
in A1
A2 = JS1.A2 - 128; // Calculate the Y offset and save it
in A2
ENDSEQUENCE
ENDSCRIPT
GUI에서 몇 가지 장치 할당을 해주어야 합니다. 우선, CombatStick의 X와 Y축은 관계
없으므로 “None”으로 바꿉니다. 그 다음, CMS.A1과 CMS.A2의 값을 CM Device 1의
X축과 Y축에 할당하여 Windows에서 수정된 값이 적용되도록 합니다.
스크립트 예제
#4 사전 변수 지정
이 예제에서는 스크립트를 처음 실행할 때 어떤 변수를 특정한 값으로 설정하는 한가지 방법을 설명합니다.
보통은, 처음 스크립트가 시작될 때는 스크립트에서 쓰는 아날로그 값은 0으로, 모든 비트 변수들은 FLASE로
설정됩니다. 대부분의 경우에는 이대로 두어도 좋지만, 다른 값이 필요할 때도 있습니다.
한가지 예는 스로틀을 조정할 때입니다. 0값은 “최대 스로틀”이며, 스크립트가 처음 시작될 때 갑자기
최대 스로틀 상태가 되는 것은 좋지 않을 것입니다.
여기서의 한가지 방법은 스크립트가 처음 진행되는지 아닌지를 알게끔 하는 것입니다. 다행히도, 이는
그리 어렵지 않습니다. 우리는 맵이 처음 시작될 때 내부 아날로그 변수들은 0으로, 비트 변수들은 FLASE로
설정된다는 것을 알고 있습니다.
따라서 내부 비트 변수로 “처음 진행”이 표시되는 내부 비트 변수를 선택하면 됩니다. 비트 변수가
FALSE이면, 맵이 초기화된 뒤 처음 실행과정에 있는 것이고 이때 원하는 변수를 지정할 수 있습니다.
그리고 난 후에는 우리가 선택한 비트 변수를 TRUE로 만들고 이후 계속 그 값을 TRUE로 남겨두면
됩니다.
The Script [스크립트 예문]
이 예문에서는 트림 자동 조정 예제에서와 조건이 같다고 가정합니다. 우리가 만들 것은 맵이 시작될 때
CMS.A1과 CMS.A2가 중앙에 있도록 하는 것입니다. 내부 비트 변수 B1을 “최초 실행” 표시로
사용할 것이며, 스크립트는 다음과 같이 됩니다:
SCRIPT
IF( NOT B1 ) THEN // If our first pass flag is false then
B1 = TRUE; // set flag TRUE so it won't run again
CMS.A1 = 128; // force the values in CMS.A1 and
CMS.A2 = 128; // CMS.A2 to 128.
ENDIF
ENDSCRIPT
이 예제에서는, CMS.A1과 CMS.A2에 필요한 것을 제외하면 GUI에 아무것도 할당하지 않습니다.
스크립트 예제
#5 복수 키값 전송
버튼 하나를 눌러서 여러 개의 키값 문장을 보내야 할 때도 있습니다. 한번 누를 때마다 다음번 문장이
전송됩니다. GUI에서는 이런 기능을 만들 수 없지만, CMS에서는 확실히 가능합니다.
이 예제에서는 간단히 CMS Controls의 몇몇 버튼으로 각각의 버튼으로 해당하는 문장들을 GUI를
이용하여 전송하도록 프로그래밍 합니다. 스크립트는 정확한 버튼을 눌렀을 때 문장들을 순환합니다.
The Script [스크립트 예제]
몇 가지의 방법이 있습니다. 가장 간단한 방법은 순열을 이용하는 것입니다. 맵에서 CombatStick
하나만을 JS1으로 사용하고 Button 2를 메시지 순환에 쓴다고 가정합니다.
또한, 4개의 메시지가 있고 이를 CMS.B1에서부터 CMS.B4까지에 적용시킨다고 가정합니다 그러면
스크립트는 다음과 같이 됩니다:
SCRIPT
SEQUENCE
WAIT(JS1.B2); // Wait the first click
CMS.B1 = TRUE; // Press CMS Controls Button 1
WAIT(JS1.B2); // Wait for the next click
CMS.B1 = FALSE; // Release CMS Control Button 1
CMS.B2 = TRUE; // Press CMS Controls Button 2
WAIT(JS1.B2); // Wait for the next click
CMS.B2 = FALSE; // Release CMS Control Button 2
CMS.B3 = TRUE; // Press CMS Controls Button 3
WAIT(JS1.B2); // Wait for the next click
CMS.B3 = FALSE; // Release CMS Control Button 3
CMS.B4 = TRUE; // Press CMS Controls Button 4
WAIT(JS1.B2); // Wait for the next click
CMS.B4 = FALSE; // Release CMS Control Button 4
ENDSEQUENCE
ENDSCRIPT
또 다른 방법으로서 SELECT 기능을 사용할 수도 있습니다. SELECT는 내부 아날로그 변수중의
하나로 제어되며, 이 값을 JS1.B2로 제어합니다.
우선 버튼이 클릭되기를 기다리고, 그 다음 새 값을 설정합니다. SELECT 구문으로 이러한 과정을
만들 수 있고, 각각의 경우에 CMS.Bx중의 하나를 출력하여 문장이 산출됩니다.
이는 다음과 같이 만들면 됩니다:
SCRIPT
SEQUENCE
WAIT( JS1.B2 ); // Wait until Button 2 is pressed
A1 = A1 + 1; // Increment our message counter
IF( [ A1 > 3 ] ) THEN // If A1 is over three then
A1 = 0; // Reset A1 to 0
ENDIF
ENDSEQUENCE
SELECT( A1, POSITION ) OF
CASE 0:
CMS.B1 = TRUE; // Set the bit for our first message
EXITCASE:
CMS.B1 = | | |
